Failed to resolve: estimote-sdk

BLE Beacons
1

Hello!! I have a problem tryin to use estimote sdk with android estudio. My app run without problem and I have tried to use Gradle via Maven Central installation option, and with

repositories {
mavenCentral()
flatDir {
dirs 'libs'
}
}

with the same result-> “Failed to resolve: estimote-sdk”

this is my build.gradle

import java.util.regex.Pattern

apply plugin: 'android'

buildscript {
    repositories {
        mavenCentral()
    }

    dependencies {
        classpath 'com.android.tools.build:gradle:2.2.2'
    }
}

ext.multiarch=false

dependencies {
    compile fileTree(include: '*.jar', dir: 'libs')
    compile(name:'estimote-sdk',ext:'aar')
    for (subproject in getProjectList()) {
        compile project(subproject)
    }

}

android {
    sourceSets {
        main {
            manifest.srcFile 'AndroidManifest.xml'
            java.srcDirs = ['src']
            resources.srcDirs = ['src']
            aidl.srcDirs = ['src']
            renderscript.srcDirs = ['src']
            res.srcDirs = ['res']
            assets.srcDirs = ['assets']
        }
    }

    defaultConfig {
        versionCode Integer.parseInt("" + getVersionCodeFromManifest() + "0")
    }

    compileSdkVersion 19
    buildToolsVersion "21.1.2"

    if (multiarch || System.env.BUILD_MULTIPLE_APKS) {
        productFlavors {
            armv7 {
                versionCode defaultConfig.versionCode + 2
                ndk {
                    abiFilters "armeabi-v7a", ""
                }
            }
            x86 {
                versionCode defaultConfig.versionCode + 4
                ndk {
                    abiFilters "x86", ""
                }
            }
            all {
                ndk {
                    abiFilters "all", ""
                }
            }
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_7
        targetCompatibility JavaVersion.VERSION_1_7
    }

}

task wrapper(type: Wrapper) {
    gradleVersion = '1.12'
}

def getVersionCodeFromManifest() {
    def manifestFile = file(android.sourceSets.main.manifest.srcFile)
    def pattern = Pattern.compile("versionCode=\"(\\d+)\"")
    def matcher = pattern.matcher(manifestFile.getText())
    matcher.find()
    return Integer.parseInt(matcher.group(1))
}

def getProjectList() {
    def manifestFile = file("project.properties")
    def pattern = Pattern.compile("android.library.reference.(\\d+)\\s*=\\s*(.*)")
    def matcher = pattern.matcher(manifestFile.getText())
    def projects = []
    while (matcher.find()) {
      projects.add(":" + matcher.group(2).replace("/",":"))
    }
    return projects
}

I have built an estimote example and it works with no problem. I really need to use beacon with this app but it seems it is impossible.

I would appreciate any help with this.

Best Regards.
Mike.

2

The code you posted is actually for the “manual” installation. If you want to do Maven (recommended) change:

compile(name:'estimote-sdk',ext:'aar')

to:

compile('com.estimote:sdk:0.13.0@aar')